Tests: Add DragNDrop as a testable CPack generator

Tests/RunCMake/CMakeLists.txt

@@ -600,6 +600,9 @@ set(cpack_tests
   STGZ
   External
   )
+if(APPLE)
+  list(APPEND cpack_tests DragNDrop)
+endif()
 add_RunCMake_test_group(CPack "${cpack_tests}")
 # add a test to make sure symbols are exported from a shared library
 # for MSVC compilers CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS property is used

Tests/RunCMake/CPack/DragNDrop/Helpers.cmake

@@ -0,0 +1,54 @@
+set(ALL_FILES_GLOB "*.dmg")
+
+function(getPackageContent FILE RESULT_VAR)
+  get_filename_component(path_ "${FILE}" DIRECTORY)
+  file(REMOVE_RECURSE "${path_}/content")
+  file(MAKE_DIRECTORY "${path_}/content")
+  execute_process(COMMAND ${HDIUTIL_EXECUTABLE} attach -mountroot ${path_}/content -nobrowse ${FILE}
+          RESULT_VARIABLE attach_result_
+          ERROR_VARIABLE attach_error_
+          OUTPUT_STRIP_TRAILING_WHITESPACE)
+
+  if(attach_result_)
+    message(FATAL_ERROR "Failed to attach DMG: '${attach_result_}';"
+          " '${attach_error_}'.")
+  endif()
+
+  file(GLOB_RECURSE package_content_ LIST_DIRECTORIES true RELATIVE
+      "${path_}/content" "${path_}/content/*")
+  # Some versions of macOS have .Trashes, others do not.
+  list(FILTER package_content_ EXCLUDE REGEX "/.Trashes$")
+  set(${RESULT_VAR} "${package_content_}" PARENT_SCOPE)
+
+  execute_process(COMMAND ${HDIUTIL_EXECUTABLE} detach ${path_}/content/volume-name
+          RESULT_VARIABLE detach_result_
+          ERROR_VARIABLE detach_error_
+          OUTPUT_STRIP_TRAILING_WHITESPACE)
+
+  if(detach_result_)
+    message(FATAL_ERROR "Failed to detach DMG: '${detach_result_}';"
+          " '${detach_error_}'.")
+  endif()
+endfunction()
+
+function(getPackageNameGlobexpr NAME COMPONENT VERSION REVISION FILE_NO RESULT_VAR)
+  if(COMPONENT)
+    set(COMPONENT "-${COMPONENT}")
+  endif()
+
+  set(${RESULT_VAR} "${NAME}-${VERSION}-Darwin${COMPONENT}.dmg" PARENT_SCOPE)
+endfunction()
+
+function(getPackageContentList FILE RESULT_VAR)
+  getPackageContent("${FILE}" package_content_)
+
+  set(${RESULT_VAR} "${package_content_}" PARENT_SCOPE)
+endfunction()
+
+function(toExpectedContentList FILE_NO CONTENT_VAR)
+  set(prefix_ "volume-name")
+  list(TRANSFORM ${CONTENT_VAR} PREPEND "${prefix_}" OUTPUT_VARIABLE prepared_)
+  list(APPEND prepared_ "${prefix_}")
+
+  set(${CONTENT_VAR} "${prepared_}" PARENT_SCOPE)
+endfunction()

Tests/RunCMake/CPack/DragNDrop/Prerequirements.cmake

@@ -0,0 +1,8 @@
+function(get_test_prerequirements found_var config_file)
+  find_program(HDIUTIL_EXECUTABLE hdiutil)
+
+  if(HDIUTIL_EXECUTABLE)
+    file(WRITE "${config_file}" "set(HDIUTIL_EXECUTABLE \"${HDIUTIL_EXECUTABLE}\")")
+    set(${found_var} true PARENT_SCOPE)
+  endif()
+endfunction()

Tests/RunCMake/CPack/DragNDrop/packaging_COMPONENT_default.cmake

@@ -0,0 +1,3 @@
+set(CPACK_COMPONENTS_GROUPING "IGNORE")
+set(CPACK_DMG_DISABLE_APPLICATIONS_SYMLINK ON)
+set(CPACK_DMG_VOLUME_NAME "volume-name")