Merge topic 'find_fontconfig'

84e7920b3a FindFontconfig: Add module to find Fontconfig

Acked-by: Kitware Robot <[email protected]>
Merge-request: !2487

Copyright.txt

@@ -64,6 +64,7 @@ The following individuals and institutions are among the Contributors:
 * Insight Software Consortium <insightsoftwareconsortium.org>
 * Jan Woetzel
 * Kelly Thompson <[email protected]>
+* Laurent Montel <[email protected]>
 * Konstantin Podsvirov <[email protected]>
 * Mario Bensi <[email protected]>
 * Martin Gräßlin <[email protected]>

Help/manual/cmake-modules.7.rst

@@ -131,6 +131,7 @@ They are normally called through the :command:`find_package` command.
    /module/FindFLEX
    /module/FindFLTK2
    /module/FindFLTK
+   /module/FindFontconfig
    /module/FindFreetype
    /module/FindGCCXML
    /module/FindGDAL

Help/module/FindFontconfig.rst

@@ -0,0 +1 @@
+.. cmake-module:: ../../Modules/FindFontconfig.cmake

Help/release/dev/find_fontconfig.rst

@@ -0,0 +1,6 @@
+find_fontconfig
+---------------
+
+* The :module:`FindFontconfig` module was added to find `fontconfig`_.
+
+.. _`fontconfig`: https://www.freedesktop.org/wiki/Software/fontconfig/

Modules/FindFontconfig.cmake

@@ -0,0 +1,101 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindFontconfig
+--------------
+
+Find Fontconfig headers and library.
+
+Imported Targets
+^^^^^^^^^^^^^^^^
+
+``Fontconfig::Fontconfig``
+  The Fontconfig library, if found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This will define the following variables in your project:
+
+``FONTCONFIG_FOUND``
+  true if (the requested version of) Fontconfig is available.
+``FONTCONFIG_VERSION``
+  the version of Fontconfig.
+``FONTCONFIG_LIBRARIES``
+  the libraries to link against to use Fontconfig.
+``FONTCONFIG_INCLUDE_DIRS``
+  where to find the Fontconfig headers.
+``FONTCONFIG_COMPILE_OPTIONS``
+  this should be passed to target_compile_options(), if the
+  target is not used for linking
+
+#]=======================================================================]
+
+
+# use pkg-config to get the directories and then use these values
+# in the FIND_PATH() and FIND_LIBRARY() calls
+find_package(PkgConfig QUIET)
+pkg_check_modules(PKG_FONTCONFIG QUIET fontconfig)
+set(FONTCONFIG_COMPILE_OPTIONS ${PKG_FONTCONFIG_CFLAGS_OTHER})
+set(FONTCONFIG_VERSION ${PKG_FONTCONFIG_VERSION})
+
+find_path( FONTCONFIG_INCLUDE_DIR
+  NAMES
+    fontconfig/fontconfig.h
+  HINTS
+    ${PKG_FONTCONFIG_INCLUDE_DIRS}
+    /usr/X11/include
+)
+
+find_library( FONTCONFIG_LIBRARY
+  NAMES
+    fontconfig
+  PATHS
+    ${PKG_FONTCONFIG_LIBRARY_DIRS}
+)
+
+if (FONTCONFIG_INCLUDE_DIR AND NOT FONTCONFIG_VERSION)
+  file(STRINGS ${FONTCONFIG_INCLUDE_DIR}/fontconfig/fontconfig.h _contents REGEX "^#define[ \t]+FC_[A-Z]+[ \t]+[0-9]+$")
+  unset(FONTCONFIG_VERSION)
+  foreach(VPART MAJOR MINOR REVISION)
+    foreach(VLINE ${_contents})
+      if(VLINE MATCHES "^#define[\t ]+FC_${VPART}[\t ]+([0-9]+)$")
+        set(FONTCONFIG_VERSION_PART "${CMAKE_MATCH_1}")
+        if(FONTCONFIG_VERSION)
+          string(APPEND FONTCONFIG_VERSION ".${FONTCONFIG_VERSION_PART}")
+        else()
+          set(FONTCONFIG_VERSION "${FONTCONFIG_VERSION_PART}")
+        endif()
+      endif()
+    endforeach()
+  endforeach()
+endif ()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Fontconfig
+  FOUND_VAR
+    FONTCONFIG_FOUND
+  REQUIRED_VARS
+    FONTCONFIG_LIBRARY
+    FONTCONFIG_INCLUDE_DIR
+  VERSION_VAR
+    FONTCONFIG_VERSION
+)
+
+
+if(FONTCONFIG_FOUND AND NOT TARGET Fontconfig::Fontconfig)
+  add_library(Fontconfig::Fontconfig UNKNOWN IMPORTED)
+  set_target_properties(Fontconfig::Fontconfig PROPERTIES
+    IMPORTED_LOCATION "${FONTCONFIG_LIBRARY}"
+    INTERFACE_COMPILE_OPTIONS "${FONTCONFIG_COMPILE_OPTIONS}"
+    INTERFACE_INCLUDE_DIRECTORIES "${FONTCONFIG_INCLUDE_DIR}"
+  )
+endif()
+
+mark_as_advanced(FONTCONFIG_LIBRARY FONTCONFIG_INCLUDE_DIR)
+
+if(FONTCONFIG_FOUND)
+  set(FONTCONFIG_LIBRARIES ${FONTCONFIG_LIBRARY})
+  set(FONTCONFIG_INCLUDE_DIRS ${FONTCONFIG_INCLUDE_DIR})
+endif()

Tests/CMakeLists.txt

@@ -1376,6 +1376,10 @@ ${CMake_BINARY_DIR}/bin/cmake -DDIR=dev -P ${CMake_SOURCE_DIR}/Utilities/Release
     add_subdirectory(FindEXPAT)
   endif()
 
+  if(CMake_TEST_FindFontconfig)
+    add_subdirectory(FindFontconfig)
+  endif()
+
   if(CMake_TEST_FindFreetype)
     add_subdirectory(FindFreetype)
   endif()

Tests/FindFontconfig/CMakeLists.txt

@@ -0,0 +1,10 @@
+add_test(NAME FindFontconfig.Test COMMAND
+  ${CMAKE_CTEST_COMMAND} -C $<CONFIGURATION>
+  --build-and-test
+  "${CMake_SOURCE_DIR}/Tests/FindFontconfig/Test"
+  "${CMake_BINARY_DIR}/Tests/FindFontconfig/Test"
+  ${build_generator_args}
+  --build-project TestFindFontconfig
+  --build-options ${build_options}
+  --test-command ${CMAKE_CTEST_COMMAND} -V -C $<CONFIGURATION>
+  )

Tests/FindFontconfig/Test/CMakeLists.txt

@@ -0,0 +1,16 @@
+cmake_minimum_required(VERSION 3.10)
+project(TestFindFontconfig C)
+include(CTest)
+
+find_package(Fontconfig REQUIRED)
+
+add_definitions(-DCMAKE_EXPECTED_FONTCONFIG_VERSION="${FONTCONFIG_VERSION}")
+
+add_executable(test_tgt main.c)
+target_link_libraries(test_tgt Fontconfig::Fontconfig)
+add_test(NAME test_tgt COMMAND test_tgt)
+
+add_executable(test_var main.c)
+target_include_directories(test_var PRIVATE ${FONTCONFIG_INCLUDE_DIRS})
+target_link_libraries(test_var PRIVATE ${FONTCONFIG_LIBRARIES})
+add_test(NAME test_var COMMAND test_var)

Tests/FindFontconfig/Test/main.c

@@ -0,0 +1,17 @@
+#include <assert.h>
+#include <fontconfig/fontconfig.h>
+#include <stdio.h>
+#include <string.h>
+
+int main()
+{
+  FcInit();
+  printf("Found Fontconfig.\n");
+
+  char fontconfig_version_string[16];
+  snprintf(fontconfig_version_string, 16, "%i.%i.%i", FC_MAJOR, FC_MINOR,
+           FC_REVISION);
+  assert(
+    strcmp(fontconfig_version_string, CMAKE_EXPECTED_FONTCONFIG_VERSION) == 0);
+  return 0;
+}