Provide macro write_basic_config_version_file()

This macro can be used to generate basic version files which can be
installed along a Config.cmake file to provide versioning support.

This (3rd try) is implemented using a macro, which maps
the COMPATIBILITY mode to a filename and configure_file()s the
resulting file.

Alex

Modules/BasicConfigVersion-AnyNewerVersion.cmake.in

@@ -0,0 +1,29 @@
+# This is a basic file for the new style find_package() search mode,
+# i.e. Config-mode.
+# It is used by WriteBasicConfigVersionFile.cmake as input file for configure_file()
+# to create a version-file which can be installed along a config.cmake file.
+#
+# The created file sets PACKAGE_VERSION_EXACT if the current version string and
+# the requested version string are exactly the same and it sets
+# PACKAGE_VERSION_COMPATIBLE if the current version is >= requested version.
+# The variable CVF_VERSION must be set before calling configure_file().
+
+set(PACKAGE_VERSION "@CVF_VERSION@")
+
+# check that the installed version has the same 32/64bit-ness as the one which is currently searching:
+if(NOT "${CMAKE_SIZEOF_VOID_P}"  STREQUAL  "@CMAKE_SIZEOF_VOID_P@")
+   math(EXPR installedBits "@CMAKE_SIZEOF_VOID_P@ * 8")
+   set(PACKAGE_VERSION "${PACKAGE_VERSION} (${installedBits}bit)")
+   set(PACKAGE_VERSION_COMPATIBLE FALSE)
+else()
+
+  if("${PACKAGE_VERSION}" VERSION_LESS "${PACKAGE_FIND_VERSION}" )
+    set(PACKAGE_VERSION_COMPATIBLE FALSE)
+  else()
+    set(PACKAGE_VERSION_COMPATIBLE TRUE)
+    if( "${PACKAGE_FIND_VERSION}" STREQUAL "${PACKAGE_VERSION}")
+        set(PACKAGE_VERSION_EXACT TRUE)
+    endif()
+  endif()
+
+endif()

Modules/BasicConfigVersion-SameMajorVersion.cmake.in

@@ -0,0 +1,43 @@
+# This is a basic file for the new style find_package() search mode,
+# i.e. Config-mode.
+# It is used by WriteBasicConfigVersionFile.cmake as input file for configure_file()
+# to create a version-file which can be installed along a config.cmake file.
+#
+# The created file sets PACKAGE_VERSION_EXACT if the current version string and
+# the requested version string are exactly the same and it sets
+# PACKAGE_VERSION_COMPATIBLE if the current version is >= requested version,
+# but only if the requested major version is the same as the current one.
+# The variable CVF_VERSION must be set before calling configure_file().
+
+
+set(PACKAGE_VERSION "@CVF_VERSION@")
+
+# check that the installed version has the same 32/64bit-ness as the one which is currently searching:
+if(NOT "${CMAKE_SIZEOF_VOID_P}" STREQUAL "@CMAKE_SIZEOF_VOID_P@")
+   math(EXPR installedBits "@CMAKE_SIZEOF_VOID_P@ * 8")
+   set(PACKAGE_VERSION "${PACKAGE_VERSION} (${installedBits}bit)")
+   set(PACKAGE_VERSION_COMPATIBLE FALSE)
+else()
+
+  if("${PACKAGE_VERSION}" VERSION_LESS "${PACKAGE_FIND_VERSION}" )
+    set(PACKAGE_VERSION_COMPATIBLE FALSE)
+  else()
+
+    if("@CVF_VERSION@" MATCHES "^([0-9]+)\\.")
+      set(CVF_VERSION_MAJOR "${CMAKE_MATCH_1}")
+    else()
+      set(CVF_VERSION_MAJOR "@CVF_VERSION@")
+    endif()
+
+    if("${PACKAGE_FIND_VERSION_MAJOR}" STREQUAL "${CVF_VERSION_MAJOR}")
+      set(PACKAGE_VERSION_COMPATIBLE TRUE)
+    else()
+      set(PACKAGE_VERSION_COMPATIBLE FALSE)
+    endif()
+
+    if( "${PACKAGE_FIND_VERSION}" STREQUAL "${PACKAGE_VERSION}")
+        set(PACKAGE_VERSION_EXACT TRUE)
+    endif()
+  endif()
+
+endif()

Modules/WriteBasicConfigVersionFile.cmake

@@ -0,0 +1,49 @@
+#  WRITE_BASIC_CONFIG_VERSION_FILE( filename VERSION major.minor.patch COMPATIBILITY (AnyNewerVersion|SameMajorVersion) )
+#
+# Writes a file for use as <package>ConfigVersion.cmake file to <filename>.
+# See the documentation of FIND_PACKAGE() for details on this.
+#    filename is the output filename, it should be in the build tree.
+#    major.minor.patch is the version number of the project to be installed
+# The COMPATIBILITY mode AnyNewerVersion means that the installed package version
+# will be considered suitable if it is newer or exactly the same as the requested version.
+# If SameMajorVersion is used instead, then the behaviour differs from AnyNewerVersion
+# in that the major version number must be the same as requested, e.g. version 2.0 will
+# not be considered suitable to 1.0 is requested.
+# If you project has more elaborated version matching rules, you will need to write your
+# own custom ConfigVersion.cmake file, instead of using this macro.
+#
+# Internally, this macro executes configure_file() on the input file
+# Modules/BasicConfigVersion-AnyNewerVersion/SameMajorVersion.cmake.in to
+# create the resulting version file.
+
+# Copyright (c) 2008, Alexander Neundorf, <[email protected]>
+#
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+
+include(CMakeParseArguments)
+
+function(WRITE_BASIC_CONFIG_VERSION_FILE _filename)
+
+  set(options )
+  set(oneValueArgs VERSION COMPATIBILITY )
+  set(multiValueArgs )
+
+  cmake_parse_arguments(CVF "${options}" "${oneValueArgs}" "${multiValueArgs}"  ${ARGN})
+
+  if(CVF_UNPARSED_ARGUMENTS)
+    message(FATAL_ERROR "Unknown keywords given to WRITE_BASIC_CONFIG_VERSION_FILE(): \"${CVF_UNPARSED_ARGUMENTS}\"")
+  endif(CVF_UNPARSED_ARGUMENTS)
+
+  set(versionTemplateFile "${CMAKE_ROOT}/Modules/BasicConfigVersion-${CVF_COMPATIBILITY}.cmake.in")
+  if(NOT EXISTS "${versionTemplateFile}")
+    message(FATAL_ERROR "Bad COMPATIBILITY value used for WRITE_BASIC_CONFIG_VERSION_FILE(): \"${CVF_COMPATIBILITY}\"")
+  endif()
+
+  if("${CVF_VERSION}" STREQUAL "")
+    message(FATAL_ERROR "No VERSION specified for WRITE_BASIC_CONFIG_VERSION_FILE()")
+  endif()
+
+  configure_file("${versionTemplateFile}" "${_filename}" @ONLY)
+
+endfunction(WRITE_BASIC_CONFIG_VERSION_FILE)

Source/cmFindPackageCommand.cxx

@@ -191,6 +191,9 @@ void cmFindPackageCommand::GenerateDocumentation()
     "\"<config-file>-version.cmake\" or \"<config-file>Version.cmake\".  "
     "If no such version file is available then the configuration file "
     "is assumed to not be compatible with any requested version.  "
+    "A basic version file containing generic version matching code can be "
+    "created using the macro write_basic_config_version_file(), see its "
+    "documentation for more details.  "
     "When a version file is found it is loaded to check the requested "
     "version number.  "
     "The version file is loaded in a nested scope in which the following "