Factor out CMake.File test result check for re-use

The CMake.File test runs several scripts through "cmake -P" and checks
the output and result against known good values.  This commit factors
out the checking code into a separate CMakeCheckTest module.  The module
may be used by new tests.

Tests/CMakeTests/CheckCMakeTest.cmake

@@ -0,0 +1,30 @@
+get_filename_component(CMakeTests_SRC_DIR ${CMAKE_CURRENT_LIST_FILE} PATH)
+function(check_cmake_test prefix)
+  get_filename_component(CMakeTests_BIN_DIR ${CMAKE_CURRENT_LIST_FILE} PATH)
+  foreach(test ${ARGN})
+    message(STATUS "Test ${prefix}-${test}...")
+    execute_process(
+      COMMAND ${CMAKE_COMMAND} -P "${CMakeTests_SRC_DIR}/${prefix}-${test}.cmake"
+      WORKING_DIRECTORY "${CMakeTests_BIN_DIR}"
+      OUTPUT_VARIABLE stdout
+      ERROR_VARIABLE stderr
+      RESULT_VARIABLE result
+      )
+    string(REGEX REPLACE "\n" "\n out> " out " out> ${stdout}")
+    string(REGEX REPLACE "\n" "\n err> " err " err> ${stderr}")
+    if(NOT "${result}" STREQUAL ${${test}-RESULT})
+      message(FATAL_ERROR
+        "Test ${test} result is [${result}], not [${${test}-RESULT}].\n"
+        "Test ${test} output:\n"
+        "${out}\n"
+        "${err}")
+    endif()
+    if(${test}-STDERR AND NOT "${err}" MATCHES "${${test}-STDERR}")
+      message(FATAL_ERROR
+        "Test ${test} stderr does not match\n  ${${test}-STDERR}\n"
+        "Test ${test} output:\n"
+        "${out}\n"
+        "${err}")
+    endif()
+  endforeach()
+endfunction()

Tests/CMakeTests/FileTest.cmake.in

@@ -13,38 +13,13 @@ set(Copy-NoDest-STDERR "given no DESTINATION")
 set(Copy-NoFile-RESULT 1)
 set(Copy-NoFile-STDERR "COPY cannot find.*/does_not_exist\\.txt")
 
-foreach(test
-    Copy-BadArg
-    Copy-BadPerm
-    Copy-BadRegex
-    Copy-EarlyArg
-    Copy-LateArg
-    Copy-NoDest
-    Copy-NoFile
-    )
-  message(STATUS "Test ${test}...")
-  execute_process(
-    COMMAND ${CMAKE_COMMAND} -P
-    "@CMAKE_CURRENT_SOURCE_DIR@/File-${test}.cmake"
-    WORKING_DIRECTORY "@CMAKE_CURRENT_BINARY_DIR@"
-    OUTPUT_VARIABLE stdout
-    ERROR_VARIABLE stderr
-    RESULT_VARIABLE result
-    )
-  string(REGEX REPLACE "\n" "\n out> " out " out> ${stdout}")
-  string(REGEX REPLACE "\n" "\n err> " err " err> ${stderr}")
-  if(NOT "${result}" STREQUAL ${${test}-RESULT})
-    message(FATAL_ERROR
-      "Test ${test} result is [${result}], not [${${test}-RESULT}].\n"
-      "Test ${test} output:\n"
-      "${out}\n"
-      "${err}")
-  endif()
-  if(${test}-STDERR AND NOT "${err}" MATCHES "${${test}-STDERR}")
-    message(FATAL_ERROR
-      "Test ${test} stderr does not match\n  ${${test}-STDERR}\n"
-      "Test ${test} output:\n"
-      "${out}\n"
-      "${err}")
-  endif()
-endforeach()
+include("@CMAKE_CURRENT_SOURCE_DIR@/CheckCMakeTest.cmake")
+check_cmake_test(File
+  Copy-BadArg
+  Copy-BadPerm
+  Copy-BadRegex
+  Copy-EarlyArg
+  Copy-LateArg
+  Copy-NoDest
+  Copy-NoFile
+  )