Tests/CXXModules: add a test to ensure that `restat` works for collation

Also update the `modules-json-file` test to account for the fact that
`CXXModules.json` is not updated for timestamp-only rebuild triggers.

See: #25511

Tests/RunCMake/CXXModules/RunCMakeTest.cmake

@@ -216,6 +216,9 @@ if ("collation" IN_LIST CMake_TEST_MODULE_COMPILATION)
   unset(RunCMake_CXXModules_NO_TEST)
   run_cxx_module_test_rebuild(depchain-modmap)
   run_cxx_module_test_rebuild(depchain-modules-json-file)
+  if (RunCMake_GENERATOR MATCHES "Ninja")
+    run_cxx_module_test_rebuild(depchain-collation-restat)
+  endif ()
 endif ()
 
 # Tests which use named modules in shared libraries.

Tests/RunCMake/CXXModules/examples/depchain-collation-restat-rebuild-check.cmake

@@ -0,0 +1,12 @@
+if (RunCMake_GENERATOR_IS_MULTI_CONFIG)
+  set(dep_collation_restat "CMakeFiles/depchain_collation_restat.dir/Debug/main.cxx${CMAKE_CXX_OUTPUT_EXTENSION}")
+  set(collation_restat "CMakeFiles/depchain_with_collation_restat.dir/Debug/CXXModules.json")
+else ()
+  set(dep_collation_restat "CMakeFiles/depchain_collation_restat.dir/main.cxx${CMAKE_CXX_OUTPUT_EXTENSION}")
+  set(collation_restat "CMakeFiles/depchain_with_collation_restat.dir/CXXModules.json")
+endif ()
+
+if (NOT "${RunCMake_TEST_BINARY_DIR}/${collation_restat}" IS_NEWER_THAN "${RunCMake_TEST_BINARY_DIR}/${dep_collation_restat}")
+  list(APPEND RunCMake_TEST_FAILED
+    "Object '${dep_collation_restat}' should not have recompiled if '${collation_restat}' did not change content.")
+endif ()

Tests/RunCMake/CXXModules/examples/depchain-collation-restat/CMakeLists.txt

@@ -0,0 +1,23 @@
+cmake_minimum_required(VERSION 3.28)
+project(cxx_modules_depchain_collation_restat CXX)
+
+include("${CMAKE_SOURCE_DIR}/../cxx-modules-rules.cmake")
+
+add_library(depchain_with_collation_restat)
+target_sources(depchain_with_collation_restat
+  PUBLIC
+    FILE_SET CXX_MODULES
+      BASE_DIRS
+        "${CMAKE_CURRENT_SOURCE_DIR}"
+      FILES
+        importable.cxx)
+target_compile_features(depchain_with_collation_restat PUBLIC cxx_std_20)
+
+add_executable(depchain_collation_restat)
+target_sources(depchain_collation_restat
+  PRIVATE
+    main.cxx)
+target_link_libraries(depchain_collation_restat
+  PRIVATE
+    depchain_with_collation_restat)
+add_test(NAME depchain_collation_restat COMMAND depchain_collation_restat)

Tests/RunCMake/CXXModules/examples/depchain-collation-restat/importable.cxx

@@ -0,0 +1,6 @@
+export module importable;
+
+export int from_import()
+{
+  return 0;
+}

Tests/RunCMake/CXXModules/examples/depchain-collation-restat/main.cxx

@@ -0,0 +1,6 @@
+import importable;
+
+int main(int argc, char* argv[])
+{
+  return from_import();
+}

Tests/RunCMake/CXXModules/examples/depchain-collation-restat/pre-rebuild.cmake

@@ -0,0 +1,7 @@
+if (RunCMake_GENERATOR_IS_MULTI_CONFIG)
+  set(collation_restat "CMakeFiles/depchain_with_collation_restat.dir/Debug/CXXModules.json")
+else ()
+  set(collation_restat "CMakeFiles/depchain_with_collation_restat.dir/CXXModules.json")
+endif ()
+
+file(TOUCH_NOCREATE "${RunCMake_TEST_BINARY_DIR}/${collation_restat}")

Tests/RunCMake/CXXModules/examples/depchain-modules-json-file-rebuild-check.cmake

@@ -1,8 +1,8 @@
 if (RunCMake_GENERATOR_IS_MULTI_CONFIG)
-  set(dep_modules_json_path "CMakeFiles/depchain_modules_json_file.dir/Debug/CXXModules.json")
+  set(dep_modules_json_path "CMakeFiles/depchain_modules_json_file.dir/Debug/CXX.dd")
   set(modules_json_path "CMakeFiles/depchain_with_modules_json_file.dir/Debug/CXXModules.json")
 else ()
-  set(dep_modules_json_path "CMakeFiles/depchain_modules_json_file.dir/CXXModules.json")
+  set(dep_modules_json_path "CMakeFiles/depchain_modules_json_file.dir/CXX.dd")
   set(modules_json_path "CMakeFiles/depchain_with_modules_json_file.dir/CXXModules.json")
 endif ()