CMake/Modules/BasicConfigVersion-AnyNewerVersion.cmake.in

# This is a basic file for the new style find_package() search mode,
# i.e. Config-mode.
# It is used by WriteBasicConfigVersionFile.cmake as input file for configure_file()
# to create a version-file which can be installed along a config.cmake file.
#
# The created file sets PACKAGE_VERSION_EXACT if the current version string and
# the requested version string are exactly the same and it sets
# PACKAGE_VERSION_COMPATIBLE if the current version is >= requested version.
# The variable CVF_VERSION must be set before calling configure_file().

set(PACKAGE_VERSION "@CVF_VERSION@")

set(PACKAGE_VERSION_EXACT FALSE) # initialize to FALSE

# check that the installed version has the same 32/64bit-ness as the one which is currently searching:
if(NOT "${CMAKE_SIZEOF_VOID_P}"  STREQUAL  "@CMAKE_SIZEOF_VOID_P@")
   math(EXPR installedBits "@CMAKE_SIZEOF_VOID_P@ * 8")
   set(PACKAGE_VERSION "${PACKAGE_VERSION} (${installedBits}bit)")
   set(PACKAGE_VERSION_COMPATIBLE FALSE)
else()

  if("${PACKAGE_VERSION}" VERSION_LESS "${PACKAGE_FIND_VERSION}" )
    set(PACKAGE_VERSION_COMPATIBLE FALSE)
  else()
    set(PACKAGE_VERSION_COMPATIBLE TRUE)
    if( "${PACKAGE_FIND_VERSION}" STREQUAL "${PACKAGE_VERSION}")
        set(PACKAGE_VERSION_EXACT TRUE)
    endif()
  endif()

endif()