CMake/Modules/ExternalProject/verify.cmake.in

# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
# file Copyright.txt or https://cmake.org/licensing for details.

cmake_minimum_required(VERSION 3.5)

if("@LOCAL@" STREQUAL "")
  message(FATAL_ERROR "LOCAL can't be empty")
endif()

if(NOT EXISTS "@LOCAL@")
  message(FATAL_ERROR "File not found: @LOCAL@")
endif()

function(do_verify)
  if("@ALGO@" STREQUAL "")
    message(WARNING "File will not be verified since no URL_HASH specified")
    return()
  endif()

  if("@EXPECT_VALUE@" STREQUAL "")
    message(FATAL_ERROR "EXPECT_VALUE can't be empty")
  endif()

  message(STATUS
"verifying file...
     file='@LOCAL@'")

  file("@ALGO@" "@LOCAL@" actual_value)

  if(NOT "${actual_value}" STREQUAL "@EXPECT_VALUE@")
    message(FATAL_ERROR
"error: @ALGO@ hash of
  @LOCAL@
does not match expected value
  expected: '@EXPECT_VALUE@'
    actual: '${actual_value}'
")
  endif()

  message(STATUS "verifying file... done")
endfunction()

do_verify()

set(extract_script "@extract_script_filename@")
if(NOT "${extract_script}" STREQUAL "")
  include("${extract_script}")
endif()