parser.y 15 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727
  1. /* SPDX-License-Identifier: GPL-2.0-only */
  2. /*
  3. * Copyright (C) 2002 Roman Zippel <[email protected]>
  4. */
  5. %{
  6. #include <ctype.h>
  7. #include <stdarg.h>
  8. #include <stdio.h>
  9. #include <stdlib.h>
  10. #include <string.h>
  11. #include <stdbool.h>
  12. #include "lkc.h"
  13. #define printd(mask, fmt...) if (cdebug & (mask)) printf(fmt)
  14. #define PRINTD 0x0001
  15. #define DEBUG_PARSE 0x0002
  16. int cdebug = PRINTD;
  17. static void yyerror(const char *err);
  18. static void zconfprint(const char *err, ...);
  19. static void zconf_error(const char *err, ...);
  20. static bool zconf_endtoken(const char *tokenname,
  21. const char *expected_tokenname);
  22. struct symbol *symbol_hash[SYMBOL_HASHSIZE];
  23. static struct menu *current_menu, *current_entry;
  24. %}
  25. %union
  26. {
  27. char *string;
  28. struct symbol *symbol;
  29. struct expr *expr;
  30. struct menu *menu;
  31. enum symbol_type type;
  32. enum variable_flavor flavor;
  33. }
  34. %token <string> T_HELPTEXT
  35. %token <string> T_WORD
  36. %token <string> T_WORD_QUOTE
  37. %token T_ALLNOCONFIG_Y
  38. %token T_BOOL
  39. %token T_CHOICE
  40. %token T_CLOSE_PAREN
  41. %token T_COLON_EQUAL
  42. %token T_COMMENT
  43. %token T_CONFIG
  44. %token T_DEFAULT
  45. %token T_DEFCONFIG_LIST
  46. %token T_DEF_BOOL
  47. %token T_DEF_TRISTATE
  48. %token T_DEPENDS
  49. %token T_ENDCHOICE
  50. %token T_ENDIF
  51. %token T_ENDMENU
  52. %token T_HELP
  53. %token T_HEX
  54. %token T_IF
  55. %token T_IMPLY
  56. %token T_INT
  57. %token T_MAINMENU
  58. %token T_MENU
  59. %token T_MENUCONFIG
  60. %token T_MODULES
  61. %token T_ON
  62. %token T_OPEN_PAREN
  63. %token T_OPTION
  64. %token T_OPTIONAL
  65. %token T_PLUS_EQUAL
  66. %token T_PROMPT
  67. %token T_RANGE
  68. %token T_RESET
  69. %token T_SELECT
  70. %token T_SOURCE
  71. %token T_STRING
  72. %token T_TRISTATE
  73. %token T_VISIBLE
  74. %token T_EOL
  75. %token <string> T_ASSIGN_VAL
  76. %left T_OR
  77. %left T_AND
  78. %left T_EQUAL T_UNEQUAL
  79. %left T_LESS T_LESS_EQUAL T_GREATER T_GREATER_EQUAL
  80. %nonassoc T_NOT
  81. %type <symbol> nonconst_symbol
  82. %type <symbol> symbol
  83. %type <type> type logic_type default
  84. %type <expr> expr
  85. %type <expr> if_expr
  86. %type <string> end
  87. %type <menu> if_entry menu_entry choice_entry
  88. %type <string> word_opt assign_val
  89. %type <flavor> assign_op
  90. %destructor {
  91. fprintf(stderr, "%s:%d: missing end statement for this entry\n",
  92. $$->file->name, $$->lineno);
  93. if (current_menu == $$)
  94. menu_end_menu();
  95. } if_entry menu_entry choice_entry
  96. %%
  97. input: mainmenu_stmt stmt_list | stmt_list;
  98. /* mainmenu entry */
  99. mainmenu_stmt: T_MAINMENU T_WORD_QUOTE T_EOL
  100. {
  101. menu_add_prompt(P_MENU, $2, NULL);
  102. };
  103. stmt_list:
  104. /* empty */
  105. | stmt_list common_stmt
  106. | stmt_list choice_stmt
  107. | stmt_list menu_stmt
  108. | stmt_list T_WORD error T_EOL { zconf_error("unknown statement \"%s\"", $2); }
  109. | stmt_list error T_EOL { zconf_error("invalid statement"); }
  110. ;
  111. common_stmt:
  112. if_stmt
  113. | comment_stmt
  114. | config_stmt
  115. | menuconfig_stmt
  116. | source_stmt
  117. | assignment_stmt
  118. ;
  119. /* config/menuconfig entry */
  120. config_entry_start: T_CONFIG nonconst_symbol T_EOL
  121. {
  122. $2->flags |= SYMBOL_OPTIONAL;
  123. menu_add_entry($2);
  124. printd(DEBUG_PARSE, "%s:%d:config %s\n", zconf_curname(), zconf_lineno(), $2->name);
  125. };
  126. config_stmt: config_entry_start config_option_list
  127. {
  128. printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
  129. };
  130. menuconfig_entry_start: T_MENUCONFIG nonconst_symbol T_EOL
  131. {
  132. $2->flags |= SYMBOL_OPTIONAL;
  133. menu_add_entry($2);
  134. printd(DEBUG_PARSE, "%s:%d:menuconfig %s\n", zconf_curname(), zconf_lineno(), $2->name);
  135. };
  136. menuconfig_stmt: menuconfig_entry_start config_option_list
  137. {
  138. if (current_entry->prompt)
  139. current_entry->prompt->type = P_MENU;
  140. else
  141. zconfprint("warning: menuconfig statement without prompt");
  142. printd(DEBUG_PARSE, "%s:%d:endconfig\n", zconf_curname(), zconf_lineno());
  143. };
  144. config_option_list:
  145. /* empty */
  146. | config_option_list config_option
  147. | config_option_list depends
  148. | config_option_list help
  149. ;
  150. config_option: type prompt_stmt_opt T_EOL
  151. {
  152. menu_set_type($1);
  153. printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
  154. zconf_curname(), zconf_lineno(),
  155. $1);
  156. };
  157. config_option: T_PROMPT T_WORD_QUOTE if_expr T_EOL
  158. {
  159. menu_add_prompt(P_PROMPT, $2, $3);
  160. printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
  161. };
  162. config_option: default expr if_expr T_EOL
  163. {
  164. menu_add_expr(P_DEFAULT, $2, $3);
  165. if ($1 != S_UNKNOWN)
  166. menu_set_type($1);
  167. printd(DEBUG_PARSE, "%s:%d:default(%u)\n",
  168. zconf_curname(), zconf_lineno(),
  169. $1);
  170. };
  171. config_option: T_SELECT nonconst_symbol if_expr T_EOL
  172. {
  173. menu_add_symbol(P_SELECT, $2, $3);
  174. printd(DEBUG_PARSE, "%s:%d:select\n", zconf_curname(), zconf_lineno());
  175. };
  176. config_option: T_IMPLY nonconst_symbol if_expr T_EOL
  177. {
  178. menu_add_symbol(P_IMPLY, $2, $3);
  179. printd(DEBUG_PARSE, "%s:%d:imply\n", zconf_curname(), zconf_lineno());
  180. };
  181. config_option: T_RANGE symbol symbol if_expr T_EOL
  182. {
  183. menu_add_expr(P_RANGE, expr_alloc_comp(E_RANGE,$2, $3), $4);
  184. printd(DEBUG_PARSE, "%s:%d:range\n", zconf_curname(), zconf_lineno());
  185. };
  186. config_option: T_OPTION T_MODULES T_EOL
  187. {
  188. menu_add_option_modules();
  189. };
  190. config_option: T_OPTION T_DEFCONFIG_LIST T_EOL
  191. {
  192. menu_add_option_defconfig_list();
  193. };
  194. config_option: T_OPTION T_ALLNOCONFIG_Y T_EOL
  195. {
  196. menu_add_option_allnoconfig_y();
  197. };
  198. /* choice entry */
  199. choice: T_CHOICE word_opt T_EOL
  200. {
  201. struct symbol *sym = sym_lookup($2, SYMBOL_CHOICE);
  202. sym->flags |= SYMBOL_NO_WRITE;
  203. menu_add_entry(sym);
  204. menu_add_expr(P_CHOICE, NULL, NULL);
  205. free($2);
  206. printd(DEBUG_PARSE, "%s:%d:choice\n", zconf_curname(), zconf_lineno());
  207. };
  208. choice_entry: choice choice_option_list
  209. {
  210. $$ = menu_add_menu();
  211. };
  212. choice_end: end
  213. {
  214. if (zconf_endtoken($1, "choice")) {
  215. menu_end_menu();
  216. printd(DEBUG_PARSE, "%s:%d:endchoice\n", zconf_curname(), zconf_lineno());
  217. }
  218. };
  219. choice_stmt: choice_entry choice_block choice_end
  220. ;
  221. choice_option_list:
  222. /* empty */
  223. | choice_option_list choice_option
  224. | choice_option_list depends
  225. | choice_option_list help
  226. ;
  227. choice_option: T_PROMPT T_WORD_QUOTE if_expr T_EOL
  228. {
  229. menu_add_prompt(P_PROMPT, $2, $3);
  230. printd(DEBUG_PARSE, "%s:%d:prompt\n", zconf_curname(), zconf_lineno());
  231. };
  232. choice_option: logic_type prompt_stmt_opt T_EOL
  233. {
  234. menu_set_type($1);
  235. printd(DEBUG_PARSE, "%s:%d:type(%u)\n",
  236. zconf_curname(), zconf_lineno(), $1);
  237. };
  238. choice_option: T_OPTIONAL T_EOL
  239. {
  240. current_entry->sym->flags |= SYMBOL_OPTIONAL;
  241. printd(DEBUG_PARSE, "%s:%d:optional\n", zconf_curname(), zconf_lineno());
  242. };
  243. choice_option: T_RESET if_expr T_EOL
  244. {
  245. menu_add_prop(P_RESET, NULL, $2);
  246. };
  247. choice_option: T_DEFAULT nonconst_symbol if_expr T_EOL
  248. {
  249. menu_add_symbol(P_DEFAULT, $2, $3);
  250. printd(DEBUG_PARSE, "%s:%d:default\n",
  251. zconf_curname(), zconf_lineno());
  252. };
  253. type:
  254. logic_type
  255. | T_INT { $$ = S_INT; }
  256. | T_HEX { $$ = S_HEX; }
  257. | T_STRING { $$ = S_STRING; }
  258. logic_type:
  259. T_BOOL { $$ = S_BOOLEAN; }
  260. | T_TRISTATE { $$ = S_TRISTATE; }
  261. default:
  262. T_DEFAULT { $$ = S_UNKNOWN; }
  263. | T_DEF_BOOL { $$ = S_BOOLEAN; }
  264. | T_DEF_TRISTATE { $$ = S_TRISTATE; }
  265. choice_block:
  266. /* empty */
  267. | choice_block common_stmt
  268. ;
  269. /* if entry */
  270. if_entry: T_IF expr T_EOL
  271. {
  272. printd(DEBUG_PARSE, "%s:%d:if\n", zconf_curname(), zconf_lineno());
  273. menu_add_entry(NULL);
  274. menu_add_dep($2);
  275. $$ = menu_add_menu();
  276. };
  277. if_end: end
  278. {
  279. if (zconf_endtoken($1, "if")) {
  280. menu_end_menu();
  281. printd(DEBUG_PARSE, "%s:%d:endif\n", zconf_curname(), zconf_lineno());
  282. }
  283. };
  284. if_stmt: if_entry stmt_list if_end
  285. ;
  286. /* menu entry */
  287. menu: T_MENU T_WORD_QUOTE T_EOL
  288. {
  289. menu_add_entry(NULL);
  290. menu_add_prompt(P_MENU, $2, NULL);
  291. printd(DEBUG_PARSE, "%s:%d:menu\n", zconf_curname(), zconf_lineno());
  292. };
  293. menu_entry: menu menu_option_list
  294. {
  295. $$ = menu_add_menu();
  296. };
  297. menu_end: end
  298. {
  299. if (zconf_endtoken($1, "menu")) {
  300. menu_end_menu();
  301. printd(DEBUG_PARSE, "%s:%d:endmenu\n", zconf_curname(), zconf_lineno());
  302. }
  303. };
  304. menu_stmt: menu_entry stmt_list menu_end
  305. ;
  306. menu_option_list:
  307. /* empty */
  308. | menu_option_list visible
  309. | menu_option_list depends
  310. ;
  311. source_stmt: T_SOURCE T_WORD_QUOTE T_EOL
  312. {
  313. printd(DEBUG_PARSE, "%s:%d:source %s\n", zconf_curname(), zconf_lineno(), $2);
  314. zconf_nextfile($2);
  315. free($2);
  316. };
  317. /* comment entry */
  318. comment: T_COMMENT T_WORD_QUOTE T_EOL
  319. {
  320. menu_add_entry(NULL);
  321. menu_add_prompt(P_COMMENT, $2, NULL);
  322. printd(DEBUG_PARSE, "%s:%d:comment\n", zconf_curname(), zconf_lineno());
  323. };
  324. comment_stmt: comment comment_option_list
  325. ;
  326. comment_option_list:
  327. /* empty */
  328. | comment_option_list depends
  329. ;
  330. /* help option */
  331. help_start: T_HELP T_EOL
  332. {
  333. printd(DEBUG_PARSE, "%s:%d:help\n", zconf_curname(), zconf_lineno());
  334. zconf_starthelp();
  335. };
  336. help: help_start T_HELPTEXT
  337. {
  338. /* Is the help text empty or all whitespace? */
  339. if ($2[strspn($2, " \f\n\r\t\v")] == '\0')
  340. zconfprint("warning: '%s' defined with blank help text",
  341. current_entry->sym->name ?: "<choice>");
  342. current_entry->help = $2;
  343. };
  344. /* depends option */
  345. depends: T_DEPENDS T_ON expr T_EOL
  346. {
  347. menu_add_dep($3);
  348. printd(DEBUG_PARSE, "%s:%d:depends on\n", zconf_curname(), zconf_lineno());
  349. };
  350. /* visibility option */
  351. visible: T_VISIBLE if_expr T_EOL
  352. {
  353. menu_add_visibility($2);
  354. };
  355. /* prompt statement */
  356. prompt_stmt_opt:
  357. /* empty */
  358. | T_WORD_QUOTE if_expr
  359. {
  360. menu_add_prompt(P_PROMPT, $1, $2);
  361. };
  362. end: T_ENDMENU T_EOL { $$ = "menu"; }
  363. | T_ENDCHOICE T_EOL { $$ = "choice"; }
  364. | T_ENDIF T_EOL { $$ = "if"; }
  365. ;
  366. if_expr: /* empty */ { $$ = NULL; }
  367. | T_IF expr { $$ = $2; }
  368. ;
  369. expr: symbol { $$ = expr_alloc_symbol($1); }
  370. | symbol T_LESS symbol { $$ = expr_alloc_comp(E_LTH, $1, $3); }
  371. | symbol T_LESS_EQUAL symbol { $$ = expr_alloc_comp(E_LEQ, $1, $3); }
  372. | symbol T_GREATER symbol { $$ = expr_alloc_comp(E_GTH, $1, $3); }
  373. | symbol T_GREATER_EQUAL symbol { $$ = expr_alloc_comp(E_GEQ, $1, $3); }
  374. | symbol T_EQUAL symbol { $$ = expr_alloc_comp(E_EQUAL, $1, $3); }
  375. | symbol T_UNEQUAL symbol { $$ = expr_alloc_comp(E_UNEQUAL, $1, $3); }
  376. | T_OPEN_PAREN expr T_CLOSE_PAREN { $$ = $2; }
  377. | T_NOT expr { $$ = expr_alloc_one(E_NOT, $2); }
  378. | expr T_OR expr { $$ = expr_alloc_two(E_OR, $1, $3); }
  379. | expr T_AND expr { $$ = expr_alloc_two(E_AND, $1, $3); }
  380. ;
  381. /* For symbol definitions, selects, etc., where quotes are not accepted */
  382. nonconst_symbol: T_WORD { $$ = sym_lookup($1, 0); free($1); };
  383. symbol: nonconst_symbol
  384. | T_WORD_QUOTE { $$ = sym_lookup($1, SYMBOL_CONST); free($1); }
  385. ;
  386. word_opt: /* empty */ { $$ = NULL; }
  387. | T_WORD
  388. /* assignment statement */
  389. assignment_stmt: T_WORD assign_op assign_val T_EOL { variable_add($1, $3, $2); free($1); free($3); }
  390. assign_op:
  391. T_EQUAL { $$ = VAR_RECURSIVE; }
  392. | T_COLON_EQUAL { $$ = VAR_SIMPLE; }
  393. | T_PLUS_EQUAL { $$ = VAR_APPEND; }
  394. ;
  395. assign_val:
  396. /* empty */ { $$ = xstrdup(""); };
  397. | T_ASSIGN_VAL
  398. ;
  399. %%
  400. void conf_parse(const char *name)
  401. {
  402. struct symbol *sym;
  403. int i;
  404. zconf_initscan(name);
  405. _menu_init();
  406. #if YYDEBUG
  407. if (getenv("ZCONF_DEBUG"))
  408. yydebug = 1;
  409. #endif
  410. yyparse();
  411. /* Variables are expanded in the parse phase. We can free them here. */
  412. variable_all_del();
  413. if (yynerrs)
  414. exit(1);
  415. if (!modules_sym)
  416. modules_sym = sym_find( "n" );
  417. if (!menu_has_prompt(&rootmenu)) {
  418. current_entry = &rootmenu;
  419. menu_add_prompt(P_MENU, "Main menu", NULL);
  420. }
  421. menu_finalize(&rootmenu);
  422. for_all_symbols(i, sym) {
  423. if (sym_check_deps(sym))
  424. yynerrs++;
  425. }
  426. if (yynerrs)
  427. exit(1);
  428. sym_set_change_count(1);
  429. }
  430. static bool zconf_endtoken(const char *tokenname,
  431. const char *expected_tokenname)
  432. {
  433. if (strcmp(tokenname, expected_tokenname)) {
  434. zconf_error("unexpected '%s' within %s block",
  435. tokenname, expected_tokenname);
  436. yynerrs++;
  437. return false;
  438. }
  439. if (current_menu->file != current_file) {
  440. zconf_error("'%s' in different file than '%s'",
  441. tokenname, expected_tokenname);
  442. fprintf(stderr, "%s:%d: location of the '%s'\n",
  443. current_menu->file->name, current_menu->lineno,
  444. expected_tokenname);
  445. yynerrs++;
  446. return false;
  447. }
  448. return true;
  449. }
  450. static void zconfprint(const char *err, ...)
  451. {
  452. va_list ap;
  453. fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
  454. va_start(ap, err);
  455. vfprintf(stderr, err, ap);
  456. va_end(ap);
  457. fprintf(stderr, "\n");
  458. }
  459. static void zconf_error(const char *err, ...)
  460. {
  461. va_list ap;
  462. yynerrs++;
  463. fprintf(stderr, "%s:%d: ", zconf_curname(), zconf_lineno());
  464. va_start(ap, err);
  465. vfprintf(stderr, err, ap);
  466. va_end(ap);
  467. fprintf(stderr, "\n");
  468. }
  469. static void yyerror(const char *err)
  470. {
  471. fprintf(stderr, "%s:%d: %s\n", zconf_curname(), zconf_lineno() + 1, err);
  472. }
  473. static void print_quoted_string(FILE *out, const char *str)
  474. {
  475. const char *p;
  476. int len;
  477. putc('"', out);
  478. while ((p = strchr(str, '"'))) {
  479. len = p - str;
  480. if (len)
  481. fprintf(out, "%.*s", len, str);
  482. fputs("\\\"", out);
  483. str = p + 1;
  484. }
  485. fputs(str, out);
  486. putc('"', out);
  487. }
  488. static void print_symbol(FILE *out, struct menu *menu)
  489. {
  490. struct symbol *sym = menu->sym;
  491. struct property *prop;
  492. if (sym_is_choice(sym))
  493. fprintf(out, "\nchoice\n");
  494. else
  495. fprintf(out, "\nconfig %s\n", sym->name);
  496. switch (sym->type) {
  497. case S_BOOLEAN:
  498. fputs(" bool\n", out);
  499. break;
  500. case S_TRISTATE:
  501. fputs(" tristate\n", out);
  502. break;
  503. case S_STRING:
  504. fputs(" string\n", out);
  505. break;
  506. case S_INT:
  507. fputs(" integer\n", out);
  508. break;
  509. case S_HEX:
  510. fputs(" hex\n", out);
  511. break;
  512. default:
  513. fputs(" ???\n", out);
  514. break;
  515. }
  516. for (prop = sym->prop; prop; prop = prop->next) {
  517. if (prop->menu != menu)
  518. continue;
  519. switch (prop->type) {
  520. case P_PROMPT:
  521. fputs(" prompt ", out);
  522. print_quoted_string(out, prop->text);
  523. if (!expr_is_yes(prop->visible.expr)) {
  524. fputs(" if ", out);
  525. expr_fprint(prop->visible.expr, out);
  526. }
  527. fputc('\n', out);
  528. break;
  529. case P_DEFAULT:
  530. fputs( " default ", out);
  531. expr_fprint(prop->expr, out);
  532. if (!expr_is_yes(prop->visible.expr)) {
  533. fputs(" if ", out);
  534. expr_fprint(prop->visible.expr, out);
  535. }
  536. fputc('\n', out);
  537. break;
  538. case P_CHOICE:
  539. fputs(" #choice value\n", out);
  540. break;
  541. case P_SELECT:
  542. fputs( " select ", out);
  543. expr_fprint(prop->expr, out);
  544. fputc('\n', out);
  545. break;
  546. case P_IMPLY:
  547. fputs( " imply ", out);
  548. expr_fprint(prop->expr, out);
  549. fputc('\n', out);
  550. break;
  551. case P_RANGE:
  552. fputs( " range ", out);
  553. expr_fprint(prop->expr, out);
  554. fputc('\n', out);
  555. break;
  556. case P_MENU:
  557. fputs( " menu ", out);
  558. print_quoted_string(out, prop->text);
  559. fputc('\n', out);
  560. break;
  561. case P_SYMBOL:
  562. fputs( " symbol ", out);
  563. fprintf(out, "%s\n", prop->menu->sym->name);
  564. break;
  565. default:
  566. fprintf(out, " unknown prop %d!\n", prop->type);
  567. break;
  568. }
  569. }
  570. if (menu->help) {
  571. int len = strlen(menu->help);
  572. while (menu->help[--len] == '\n')
  573. menu->help[len] = 0;
  574. fprintf(out, " help\n%s\n", menu->help);
  575. }
  576. }
  577. void zconfdump(FILE *out)
  578. {
  579. struct property *prop;
  580. struct symbol *sym;
  581. struct menu *menu;
  582. menu = rootmenu.list;
  583. while (menu) {
  584. if ((sym = menu->sym))
  585. print_symbol(out, menu);
  586. else if ((prop = menu->prompt)) {
  587. switch (prop->type) {
  588. case P_COMMENT:
  589. fputs("\ncomment ", out);
  590. print_quoted_string(out, prop->text);
  591. fputs("\n", out);
  592. break;
  593. case P_MENU:
  594. fputs("\nmenu ", out);
  595. print_quoted_string(out, prop->text);
  596. fputs("\n", out);
  597. break;
  598. default:
  599. ;
  600. }
  601. if (!expr_is_yes(prop->visible.expr)) {
  602. fputs(" depends ", out);
  603. expr_fprint(prop->visible.expr, out);
  604. fputc('\n', out);
  605. }
  606. }
  607. if (menu->list)
  608. menu = menu->list;
  609. else if (menu->next)
  610. menu = menu->next;
  611. else while ((menu = menu->parent)) {
  612. if (menu->prompt && menu->prompt->type == P_MENU)
  613. fputs("\nendmenu\n", out);
  614. if (menu->next) {
  615. menu = menu->next;
  616. break;
  617. }
  618. }
  619. }
  620. }
  621. #include "menu.c"